/*

		///////////////////////////////////////////////////////////////////////
		//-------------------- CUSTOM SPRAY MANAGEMENT ----------------------//
		///////////////////////////////////////////////////////////////////////
		//------------------------- BY -=_|R0CK|_=- -------------------------//
		///////////////////////////////////////////////////////////////////////

cspray_customtype <0, 1 ,2, 3, 4>

	0 = Block All Sprays for Everyone
	1 = Custom Sprays Enabled For Everyone
	2 = Custom Sprays Enabled For Admins Disabled for others
	3 = Custom Sprays Enabled For Chosen Ones Disabled for others(amx_allowspray <name>)
	4 = Custom Sprays Disabled For Everyone (Same Logo)

cspray_distannouce <0, 1>

	0 = Distance Checker + AnnounceType Disabled
	1 = Distance Checker + AnnounceType Enabled

cspray_distannoucetype <0, 1>

	0 = All Will able to see distance between spray and ground if any one sprays
	1 = Only sprayer will be able to see distance of its own spray

cspray_timeinterval <time>

	time = Will set time interval between two sprays by a user
	
cspray_disallowtype <1, 0> (when amx_disallowspray has been used on a user)

	0 = the users custom spray is blocked only
	1 = the users spray is fully blocked
	
Admin Commands :- 

	amx_allowspray <name> <time> (will allow the person to use his own spray When Spray_CustomType = 2, 3, 4)
	amx_disallowspray <name> (will block the person's spray When Spray_CustomType = 1, 3)

*/

////////////////////////////////////////////////////////
//-------------------- INCLUDES ----------------------//
////////////////////////////////////////////////////////

#include <amxmodx>
#include <amxmisc>
#include <engine>
#include <fakemeta>
#include <hamsandwich>
#include <colorchat>
#include <xs>

///////////////////////////////////////////////////////
//-------------------- DEFINES ----------------------//
///////////////////////////////////////////////////////

#define PLUGIN 					"Custom Spray Management"
#define VERSION 				"2.1"
#define AUTHOR 					"-=_|R0CK|_=-"
#define PREFIX 					"^x03[Custom Spray]^x04"

#define FLAGS_SPRAY 			ADMIN_RCON
#define SetCustomSpray(%1)		(set_pdata_int(%1, 485, 1)) //m_nCustomFrames = 485
#define ClearCustomSpray(%1)	(set_pdata_int(%1, 485, -1)) //m_nCustomFrames = 485
#define CustomSprayTime(%1,%2)	(set_pdata_int(%1, 486, %2)) // m_flNextDecalTime (time interval for a single user) = 486

///////////////////////////////////////////////////////
//--------------------CONSTANTS----------------------//
///////////////////////////////////////////////////////
enum _:BannedData
{
	BannedSteamID[35],
	BannedName[33]
}

new Array: g_DataArray
new Trie: g_SprayBanned

new bool: gb_IsSprayAllowed[33]

new gi_LastSpray[33]
new gi_SprayTime[33]
new gi_TotalBans

new gp_CustomSpray
new gp_SprayDistType
new gp_SprayDist
new gp_SprayInterval
new gp_BlockType


///////////////////////////////////////////////////////
//--------------------- BRAIN -----------------------//
///////////////////////////////////////////////////////

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_dictionary_colored("spraymanagement.txt")
	
	gp_CustomSpray = register_cvar("cspray_customtype","1")
	gp_SprayDist = register_cvar("cspray_distannouce","0")
	gp_SprayDistType = register_cvar("cspray_distannouceType","0")
	gp_SprayInterval = register_cvar("cspray_timeinterval", "30")
	gp_BlockType = register_cvar("cspray_disallowtype", "0")
	
	register_clcmd("amx_allowspray", "Admin_AllowSpray", FLAGS_SPRAY,"<name> [time] , time between consecutive sprays")
	register_clcmd("amx_disallowspray", "Admin_DisallowSpray", FLAGS_SPRAY, "<name> , name of player")
	
	RegisterHam(Ham_Spawn, "player", "Ham_Playerspawn", 1)
	register_event("23", "Event_Spray", "a", "1=112" )
	register_impulse(201, "impulse_201")
	
	server_cmd("sv_allowupload 1")
	server_cmd("sv_allowdownload 1")
	
	g_DataArray = ArrayCreate(BannedData)
	g_SprayBanned = TrieCreate()
	LoadBans()
}

////////////////////////////////////////////////////////
//------------------ CLIENT SPAWN --------------------//
////////////////////////////////////////////////////////

public Ham_Playerspawn(id)
{
	if(!is_user_alive(id))
		return HAM_IGNORED
	
	new szBannedId[35]
	get_user_authid(id, szBannedId, charsmax(szBannedId))
	
	if(TrieKeyExists(g_SprayBanned, szBannedId))
	{
		ClearCustomSpray(id)
		client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_DIS_ONE")
	}	
	else
	{
		switch(get_pcvar_num(gp_CustomSpray))
		{
			case 0:
			{
				SetCustomSpray(id)
				client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_BLOCKED")
			}			
			case 2: 
			{
				if(access(id, FLAGS_SPRAY))
				{
					SetCustomSpray(id)
					client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_ENABLED_ADMIN")
				}	
				else
				{
					ClearCustomSpray(id)
					client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_DIS_ONE")
				}
			}
		
			case 3: 
			{
				if(gb_IsSprayAllowed[id])
				{
					SetCustomSpray(id)
					client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_ENABLED_ONE")
				}	
				else
				{
					ClearCustomSpray(id)
					client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_DIS_ONE")
				}
			}
		
			case 4: 
			{
				ClearCustomSpray(id)
				client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_DISABLED")
			}
			
			default:
			{	
				SetCustomSpray(id)
				client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_ENABLED")
			}
		}
	}
	
	if(!gb_IsSprayAllowed[id])
		gi_SprayTime[id] = get_pcvar_num(gp_SprayInterval)
	
	return HAM_IGNORED
}

////////////////////////////////////////////////////////
//----------------- ADMIN COMMANDS -------------------//
////////////////////////////////////////////////////////

public Admin_AllowSpray(id, level, cid)
{
	if(!cmd_access(id, level, cid, 1))
		return PLUGIN_HANDLED
	
	new player, user[32], iTime[21], TotalTime
	
	read_argv(1, user, charsmax(user))
	read_argv(2, iTime, charsmax(iTime))
	
	player = cmd_target(id, user, CMDTARGET_ALLOW_SELF)
	TotalTime = str_to_num(iTime)
	
	if(!is_user_connected(player))
		return PLUGIN_HANDLED
	
	if(!cmd_access(player, level, cid, 999) || id == player)
	{
		new szBannedId[35]
		get_user_authid(player, szBannedId, charsmax(szBannedId))
		
		SetCustomSpray(player)
		gb_IsSprayAllowed[player] = true
		client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_ENABLED_ONE")
		
		if(TrieKeyExists(g_SprayBanned, szBannedId))
		{
			new data[BannedData]
			for(new i = 0; i < gi_TotalBans; i++)
			{
				ArrayGetArray(g_DataArray, i, data)
				if(equal(szBannedId, data[BannedSteamID]))
				{
					ArrayDeleteItem(g_DataArray, i)
					TrieDeleteKey(g_SprayBanned, szBannedId)
					gi_TotalBans--
					SaveBans()
					break
				}
			}
		}
		
		if(TotalTime > 0)
			gi_SprayTime[player] = TotalTime
	}
	return PLUGIN_HANDLED
}

public Admin_DisallowSpray(id, level, cid)
{
	if(!cmd_access(id, level, cid, 1))
		return PLUGIN_HANDLED
	
	new player, user[32]
	read_argv(1, user, charsmax(user))
	player = cmd_target(id, user, CMDTARGET_ALLOW_SELF)
	
	if(!is_user_connected(player))
		return PLUGIN_HANDLED
	
	if(!cmd_access(player, level, cid, 999) || id == player)
	{
		ClearCustomSpray(player)
		gb_IsSprayAllowed[player] = false
		client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_DIS_ONE")
		Save_SprayBan(player)
		
		gi_SprayTime[player] = get_pcvar_num(gp_SprayInterval)
	}
	return PLUGIN_HANDLED
}
///////////////////////////////////////////////////////
//----------------- SPRAY CONTROL -------------------//
///////////////////////////////////////////////////////

public impulse_201(id) 
{
	new szBannedId[35]
	get_user_authid(id, szBannedId, charsmax(szBannedId))
	
	if(!get_pcvar_num(gp_CustomSpray) || (get_pcvar_num(gp_BlockType) && TrieKeyExists(g_SprayBanned, szBannedId)))
	{
		client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_BLOCKED")
		return PLUGIN_HANDLED
	}
	else
	{
		if(get_systime() - gi_LastSpray[id] < gi_SprayTime[id])
		{
			client_print_color(id, RED, "%s %L", PREFIX, id,"SPRAY_RECHARGE", (gi_SprayTime[id] - (get_systime() - gi_LastSpray[id])))
			return PLUGIN_HANDLED
		}
		gi_LastSpray[id] = get_systime()
		CustomSprayTime(id, gi_SprayTime[id])
	}
	return PLUGIN_CONTINUE
}

////////////////////////////////////////////////////////
//----------------- SPRAY DISTANCE -------------------//
////////////////////////////////////////////////////////
//------------------ BY:- Exolent --------------------//
////////////////////////////////////////////////////////

public Event_Spray()
{
	if(!get_pcvar_num(gp_SprayDist))
		return PLUGIN_CONTINUE
		
	new Float:vecSprayOrigin[3]
	read_data(3, vecSprayOrigin[0])
	read_data(4, vecSprayOrigin[1])
	read_data(5, vecSprayOrigin[2])
	
	new iPlayer = read_data(2)
	
	new Float:vecPlayerOrigin[3]
	pev(iPlayer, pev_origin, vecPlayerOrigin)
	
	new Float:vecDirection[3]
	xs_vec_sub(vecSprayOrigin, vecPlayerOrigin, vecDirection)
	xs_vec_mul_scalar(vecDirection, 10.0 / vector_length(vecDirection), vecDirection)

	new Float:vecStop[3]
	xs_vec_add(vecSprayOrigin, vecDirection, vecStop)
	xs_vec_mul_scalar(vecDirection, -1.0, vecDirection)
	
	new Float:vecStart[3]
	xs_vec_add(vecSprayOrigin, vecDirection, vecStart)
	engfunc(EngFunc_TraceLine, vecStart, vecStop, IGNORE_MONSTERS, -1, 0)
	get_tr2(0, TR_vecPlaneNormal, vecDirection)
	vecDirection[2] = 0.0
	
	xs_vec_mul_scalar(vecDirection, 5.0 / vector_length(vecDirection), vecDirection)
	xs_vec_add(vecSprayOrigin, vecDirection, vecStart)
	xs_vec_copy(vecStart, vecStop)
	vecStop[2] -= 9999.0
	
	engfunc(EngFunc_TraceLine, vecStart, vecStop, IGNORE_MONSTERS, -1, 0)
	get_tr2(0, TR_vecEndPos, vecStop)

	new Float: spray_dist = vecStart[2] - vecStop[2]
   
	new szName[33]
	get_user_name(iPlayer, szName, charsmax(szName))
		
	if(get_pcvar_num(gp_SprayDistType))
		client_print_color(iPlayer, RED, "%s %L", PREFIX, iPlayer,"SPRAY_DIST_UNITS", szName, spray_dist)
	else
		client_print_color(0, RED, "%s %L", PREFIX, LANG_PLAYER,"SPRAY_DIST_UNITS", szName, spray_dist)
	
	return PLUGIN_CONTINUE
}

/////////////////////////////////////////////////////////
//----------------- SAVING BAN FILE -------------------//
/////////////////////////////////////////////////////////

public Save_SprayBan(id)
{
	new data[BannedData]
	get_user_name(id, data[BannedName], charsmax(data[BannedName]))
	get_user_authid(id, data[BannedSteamID], charsmax(data[BannedSteamID]))
	
	TrieSetCell(g_SprayBanned, data[BannedSteamID], 1)
	ArrayPushArray(g_DataArray, data)
	gi_TotalBans++
	
	SaveBans()
}

SaveBans()
{
	new gp_Config[128], gp_ConfigFile[256]
	get_localinfo("amxx_configsdir", gp_Config, charsmax(gp_Config))
	formatex(gp_ConfigFile, charsmax(gp_ConfigFile), "%s/CustomSprayBanned.ini", gp_Config)
	
	if(gi_TotalBans <= 0)
	{
		delete_file(gp_ConfigFile)
		return
	}
	
	new iFile = fopen(gp_ConfigFile, "wt")
	new data[BannedData]
	
	for(new i = 0; i < gi_TotalBans; i++)
	{
		ArrayGetArray(g_DataArray, i, data)
		fprintf(iFile, "^"%s^" ^"%s^"^n", data[BannedSteamID], data[BannedName])
	}
	fclose(iFile)
}
///////////////////////////////////////////////////////
//----------------- LOAD BAN FILE -------------------//
///////////////////////////////////////////////////////

LoadBans()
{
	new gp_Config[128], gp_ConfigFile[256]
	get_localinfo("amxx_configsdir", gp_Config, charsmax(gp_Config))
	formatex(gp_ConfigFile, charsmax(gp_ConfigFile), "%s/CustomSprayBanned.ini", gp_Config)
	
	new iFile = fopen(gp_ConfigFile, "rt")
	
	if(!iFile) 
		return
	
	new szData[128], data[BannedData]
	
	while(!feof(iFile))
	{
		fgets(iFile, szData, charsmax(szData))
		trim(szData)
			
		if(!szData[0] || szData[0] == ';' || szData[0] == ' ') 
			continue

		parse(szData, data[BannedSteamID], charsmax(data[BannedSteamID]), data[BannedName], charsmax(data[BannedName]))
		TrieSetCell(g_SprayBanned, data[BannedSteamID], 1)
		ArrayPushArray(g_DataArray, data)
		
		gi_TotalBans++
	}
	fclose(iFile)
}
////////////////////////////////////////////////////////
//------------------- PLUGIN END ---------------------//
////////////////////////////////////////////////////////

public plugin_end()
{
	ArrayDestroy(g_DataArray)
	TrieDestroy(g_SprayBanned)
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ ansicpg1252\\ deff0{\\ fonttbl{\\ f0\\ fnil\\ fcharset0 Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1037\\ f0\\ fs16 \n\\ par }
*/